(ns clojure-sql.core
  (:refer-clojure :exclude [sort take drop])
  (:require [clojure.set :as set]
            [clojure-sql.compiler :as c]
            [clojure-sql.dsl :as d]
            [clojure-sql.query :as q]
            [clojure-sql.util :as u]
            [clojure.walk]))

(defmacro ^:private pull [ns & vlist]
  `(do ~@(for [i vlist
               :let [sym (symbol (name ns) (name i))]] 
           `(def ~(with-meta i
                    (u/map-vals (fn [x] `(quote ~x)) (meta (resolve sym))))
              ~sym))
       nil))

(pull clojure-sql.dsl
      table join
      project rename distinct
      prefix-names-matching prefix-names as-subobject
      select
      group
      sort take drop
      union intersection
      set-default-query-executor!)

(defmethod print-method clojure_sql.query.Query [query writer]
  (binding [*out* writer]
    (pr (c/compile-select nil query))))


(defn run-query
  "Run a select query. Return value is determined by query executor."
  [query]
  (assert (:executor query) "Cannot execute a query without a query executor")
  (q/query (:executor query) query))

(defn insert!
  "Insert a number of records into a table, setting each column to the
  corresponding value from the record. Return value is determined by
  query executor."
  [query & records]
  (assert (:executor query) "Cannot execute a query without a query executor")
  (q/insert! (:executor query) query records))

(defn update!
  "Update everything which would have been selected by the query,
  setting each field in the query to the corresponding column in the
  table. Return value is determined by query executor.

  NOTE: if the map does not have a given key then this will result in
  a NULL being included in the query. To avoid this restrict the query
  with `project` before calling `update!`."

  [query partial-record]
  (assert (:executor query) "Cannot execute a query without a query executor")
  (q/update! (:executor query) query partial-record))

(defn delete!
  "Delete everything which would have been selected by the
  query. Return value is determined by query executor."
  [query]
  (assert (:executor query) "Cannot execute a query without a query executor")
  (q/delete! (:executor query) query))

(join (-> (table :x)
          (project [:a :b]))
      (-> (table :x)
          (project [:a :b])
          distinct))